radius = 12.25;
len = 40;
wall = 4;

screw_radius = 1.5;
screw_head_radius = 2.5;
screw_head_h = 2;

screw_hole_pos = [
   [screw_radius+wall,          -screw_radius-wall,    0],
   [radius*2+wall-screw_radius, -screw_radius-wall,    0],
   [radius*2+wall-screw_radius, len+screw_radius+wall, 0],
   [screw_radius+wall,          len+screw_radius+wall, 0],
];

module screw_hole() {
    union() {
        translate([0, 0, -1])cylinder(r=screw_radius, h=wall+2);
        translate([0, 0, wall-screw_head_h]) 
            cylinder(r1=screw_radius, r2=screw_head_radius, h=screw_head_h+0.1);
    }
}

difference() {
    union() {
        cube([(radius+wall)*2, len, radius+wall]);
        hull() {
            translate(screw_hole_pos[0]) cylinder(r=screw_radius+wall, h=wall);
            translate(screw_hole_pos[2]) cylinder(r=screw_radius+wall, h=wall);
        }
        hull() {
            translate(screw_hole_pos[1]) cylinder(r=screw_radius+wall, h=wall);
            translate(screw_hole_pos[3]) cylinder(r=screw_radius+wall, h=wall);
        }
        translate([screw_radius+wall, -screw_radius-wall, 0]) 
            cube([(radius-screw_radius)*2, screw_radius+wall, wall]);
        translate([screw_radius+wall, len, 0]) 
            cube([(radius-screw_radius)*2, screw_radius+wall, wall]);
    }
    translate([radius+wall, -1, radius+wall]) 
        rotate([-90, 0, 0]) cylinder(r=radius, h=len+2);
    for (i = [0:3]) {
       translate(screw_hole_pos[i]) screw_hole();
    }
}