radius = 12.25;
len = 40;
wall = 4;

screw_radius = 1.5;
screw_head_radius = 2.5;
screw_head_h = 2;

module screw_hole() {
    union() {
        translate([0, 0, -1])cylinder(r=screw_radius, h=wall+2);
        translate([0, 0, wall-screw_head_h]) 
            cylinder(r1=screw_radius, r2=screw_head_radius, h=screw_head_h+0.1);
    }
}

difference() {
    union() {
        translate([wall, 0, 0]) 
            cube([len-wall*2, (radius+wall)*2, radius+wall]);
        hull() {
            translate([screw_radius+wall, -screw_radius-wall, 0]) 
                cylinder(r=screw_radius+wall, h=wall);
            translate([len-screw_radius-wall, radius*2+wall*3+screw_radius, 0]) 
                cylinder(r=screw_radius+wall, h=wall);
        }
        hull() {
            translate([screw_radius+wall, radius*2+wall*3+screw_radius, 0]) 
                cylinder(r=screw_radius+wall, h=wall);
            translate([len-screw_radius-wall, -screw_radius-wall, 0]) 
                cylinder(r=screw_radius+wall, h=wall);
        }
        translate([screw_radius+wall, -screw_radius-wall, 0]) 
            cube([len-(screw_radius+wall)*2, screw_radius+wall, wall]);
        translate([screw_radius+wall, (radius+wall)*2, 0]) 
            cube([len-(screw_radius+wall)*2, screw_radius+wall, wall]);
    }
    translate([-1, radius+wall, radius+wall]) rotate([0, 90, 0]) cylinder(r=radius, h=len+2);
        translate([screw_radius+wall, -screw_radius-wall, 0])
            screw_hole();
        translate([len-screw_radius-wall, radius*2+wall*3+screw_radius, 0])
            screw_hole();
        translate([screw_radius+wall, radius*2+wall*3+screw_radius, 0])
            screw_hole();
        translate([len-screw_radius-wall, -screw_radius-wall, 0])
            screw_hole();
}