module foot(radius,wall,len,foot_radius,foot_height,angle,hole_radius,hole_dist,end=true,hole=true,circlet=true) {

    cut_h = (radius+wall)*sin(angle);
    cut_r = (radius+wall)/cos(angle);

    difference() {
        union() {
            difference() {
                rotate([0,angle,0]) cylinder(r=radius + wall, h = len);
                translate([0,0,-cut_h]) cylinder(r=cut_r, h=cut_h);
            }
            translate([0,0,-0.01]) cylinder(r = foot_radius, h = foot_height);
            if (circlet) {
                translate([-(wall+radius),0,foot_height+2]) rotate([90, 0, 0]) difference() {
                    cylinder(r=8, h=4, center=true);
                    cylinder(r=4, h=5, center=true);
                }
            }
            if (end) {
                translate([cut_r,0,radius+wall]) rotate([0,90,0]) 
                    cylinder(r=radius + wall, h = len);
            }
        }
        if (circlet) {
            rotate([0, angle, 0]) translate([0,0, radius * sin(angle) + foot_height]) cylinder(r = radius, h = len);
        }
        if (hole) {
            translate([0,foot_radius - hole_dist,-1]) cylinder(r=hole_radius, h=foot_height + 2);
            translate([0,-foot_radius + hole_dist,-1]) cylinder(r=hole_radius, h=foot_height + 2);
        }
        if (end) {
            translate([cut_r+wall/2,0,radius+wall]) rotate([0,90,0]) 
                translate([0,0,wall]) cylinder(r=radius, h=len);
        }
    }
}

module t_connector(radius, wall, len, angle) {
    rotate([90,0,0]) difference() {
        union() {
            cylinder(r=radius + wall, h=len*2, center=true);
            rotate([0, angle, 0]) cylinder(r=radius + wall, h=len);
        }
        translate([0,0,len/2+wall/2]) cylinder(r=radius, h=len, center=true);
        translate([0,0,-len/2-wall/2]) cylinder(r=radius, h=len, center=true);
        rotate([0, angle, 0]) translate([0, 0, radius+wall]) cylinder(r=radius, h=len);
    }
}

module star_connector(radius, wall, len, angles) {
    rotate([90,0,0]) difference() {
        union() {
            sphere(r=radius + wall);
            for (a = angles) {
                rotate([0, a, 0]) cylinder(r=radius + wall, h=len);
            }
        }
        for (a = angles) {
            rotate([0, a, 0]) translate([0, 0, radius+wall]) cylinder(r=radius, h=len);
        }
    }
}

module cross_connector(radius, wall, len, angle) {
    cc_cylinder_len = len + (radius+wall)*tan(angle)*2;
    intersection() {
        difference() {
            union() {
                translate([0, radius, 0]) rotate([0, angle, 0])
                    cylinder(r=radius + wall, h=cc_cylinder_len, center=true);
                translate([0, -radius, 0]) rotate([0, -angle, 0])
                    cylinder(r=radius + wall, h=cc_cylinder_len, center=true);
            }
            translate([0, radius + 0.2, 0]) rotate([0, angle, 0])
                cylinder(r=radius, h=cc_cylinder_len+2, center=true);
            translate([0, -radius + 0.2, 0]) rotate([0, -angle, 0])
                cylinder(r=radius, h=cc_cylinder_len+2, center=true);
        }
        cube([(len+radius)*2, (len+radius)*2, len*sin(90-angle)], center=true);
    }
}