use <utils.scad>

module d4(size=false, side=false) {
    l = side ? side : s2s_d4(size);
    if (l == false) {
        echo("ERROR: d4: one of side or size should be defined");
    }
    r = sqrt(6)/4*l;
    c = r*2;
    difference() {
        intersection() {
            sphere(r=r*0.79, $fn=64);
            translate([0, 0, r-r/3]) cube(c, center=true);
            intersection_for ( i = [0:2] ) {
                rotate([0, 0, 120*i]) rotate([acos(1/3)+180, 0, 0]) 
                    translate([0, 0, r-r/3]) cube(c, center=true);
            }
        }
        rotate([180, 0, 0]) translate([0, 0, r/3]) child(0);
        rotate([acos(1/3)+180, 0, 0]) rotate([180, 0, 0]) translate([0, 0, r/3]) child(1);
        rotate([0, 0, 120]) rotate([acos(1/3)+180, 0, 0]) rotate([180, 0, 0]) translate([0, 0, r/3]) child(2);
        rotate([0, 0, 240]) rotate([acos(1/3)+180, 0, 0]) rotate([180, 0, 0]) translate([0, 0, r/3]) child(3);
    }
}

module d6(size=false, side=false) {
    l = side ? side : s2s_d6(size);
    if (l == false) {
        echo("ERROR: d6: one of side or size should be defined");
    }
    difference() {
        intersection() {
            cube(l, center=true);
            sphere(l*0.79);
        }
        translate([0, 0, l/2]) child(0);
        rotate([90, 0, 0]) translate([0, 0, l/2]) child(1);
        rotate([0, 90, 0]) translate([0, 0, l/2]) child(2);
        rotate([-90, 0, 0]) translate([0, 0, l/2]) child(3);
        rotate([0, -90, 0]) translate([0, 0, l/2]) child(4);
        rotate([180, 0, 0]) translate([0, 0, l/2]) child(5);
    }
}

module d8(size=false, side=false) {
    l = side ? side : s2s_d8(size);
    if (l == false) {
        echo("ERROR: d8: one of side or size should be defined");
    }
    r = sqrt(2)/2*l;
    c = r*2;
    i_r = sqrt(6)/6*l;
    difference() {
        intersection() {
            sphere(r*0.86, $fn=64);
            cube([c, c, i_r*2], center=true);
            intersection_for ( i = [0:2] ) {

                rotate([0, 0, 120*i]) rotate([acos(-1/3), 0, 0]) cube([c, c, i_r*2], center=true);
            }
        }
        translate([0, 0, i_r]) child(0);
        rotate([acos(-1/3), 0, 0]) translate([0, 0, i_r]) child(1);
        rotate([0, 0, 120]) rotate([acos(-1/3)+180, 0, 0]) translate([0, 0, i_r]) child(2);
        rotate([0, 0, -120]) rotate([acos(-1/3)+180, 0, 0]) translate([0, 0, i_r]) child(3);
        rotate([0, 0, -120]) rotate([acos(-1/3), 0, 0]) translate([0, 0, i_r]) child(4);
        rotate([0, 0, 120]) rotate([acos(-1/3), 0, 0]) translate([0, 0, i_r]) child(5);
        rotate([acos(-1/3)+180, 0, 0]) translate([0, 0, i_r]) child(6);
        rotate([180, 0, 0]) translate([0, 0, i_r]) child(0);
    }
}